home *** CD-ROM | disk | FTP | other *** search
/ HTBasic 9.3 / HTBasic 9.3.iso / 93win / data1.cab / Basic_Plus_Examples / COMBTEST < prev    next >
Encoding:
Text File  |  2005-03-02  |  1.7 KB  |  47 lines
  1. 10    ! ********************************************************
  2. 20    ! Example: COMBO Test 
  3. 40    ! This program creates a COMBO widget and allows the
  4. 50    ! user to select an animal name from a defined list
  5. 60    ! of names or to enter a name from the keyboard. The
  6. 70    ! program displays an error message if the name entered
  7. 80    ! is not in the defined list.  
  8. 100    ! ********************************************************
  9. 110   !
  10. 120       DIM L$(1:5)[26],S$[50]
  11. 130       INTEGER N
  12. 140   !
  13. 150       DATA " Aardvark"," Sidewinder"," Kiwi"," Pangolin"," Marmoset"
  14. 160       READ L$(*)
  15. 170   !
  16. 180       ASSIGN @Combo TO WIDGET "COMBO";SET ("SYSTEM MENU":"Quit")
  17. 190       CONTROL @Combo;SET ("TITLE":" Example: COMBO Test - Select an Animal")
  18. 200       CONTROL @Combo;SET ("BACKGROUND":1,"LIST BACKGROUND":1,"ITEMS":L$(*))
  19. 210       CONTROL @Combo;SET ("X":50,"Y":25,"WIDTH":325)
  20. 220       CONTROL @Combo;SET ("SYSTEM MENU":"Quit")
  21. 230   !
  22. 240       ON EVENT @Combo,"SELECTION" GOSUB Handler
  23. 250       ON EVENT @Combo,"RETURN" GOSUB Handler
  24. 260       ON EVENT @Combo,"SYSTEM MENU" GOTO Finis
  25. 270   !
  26. 280       LOOP
  27. 290           WAIT FOR EVENT
  28. 300       END LOOP
  29. 310       STOP
  30. 320      !
  31. 330  Handler:!
  32. 340       STATUS @Combo;RETURN ("TEXT":S$)
  33. 350       FOR N=1 TO 5
  34. 360           IF S$=L$(N) THEN
  35. 370               S$="List item #"&VAL$(N)&": "&S$
  36. 380               DIALOG "INFORMATION",S$
  37. 390               RETURN
  38. 400           END IF
  39. 410       NEXT N
  40. 420       S$="Animal not in list: "&S$
  41. 430       DIALOG "ERROR",S$;SET ("TITLE":" Invalid Selection")
  42. 440       RETURN
  43. 450      !
  44. 460  Finis:!
  45. 470       ASSIGN @Combo TO *! Delete COMBO widget
  46. 480       END
  47.